|
|
Our Hot Pick: Rising Antivirus 2006 - Certified by TUV & Checkmark! Get 10% discount by entering this coupon code: ONDISCOUNT10
In a Macro I am creating, I need to import a delimited text file. Rather
than using a simple text box for someone to enter the file name, can a
dialogue box open so that the user can browse to find the correct file?
Right now in the TransferText action in the Macro, I use the following for
the filename:
=InputBox("Filename")
Is there a simple way to replace this input box with a file browsing box?
|
|
use as form (pop-up)
"JornyO" <JornyO[ at ]discussions.microsoft.com> wrote in message
news:CD7CD70C-80DC-4B3E-A564-91D3556F2E5F[ at ]microsoft.com...
[Quoted Text] > In a Macro I am creating, I need to import a delimited text file. Rather
> than using a simple text box for someone to enter the file name, can a
> dialogue box open so that the user can browse to find the correct file?
>
> Right now in the TransferText action in the Macro, I use the following for
> the filename:
> =InputBox("Filename")
>
> Is there a simple way to replace this input box with a file browsing box?
|
|
My apologies for being so dim-witted, but how do I go about doing that? I'm
new-ish to macros and SQL, so I'm a little hazy on how exactly to create a
pop-up.
"bob" wrote:
[Quoted Text] > use as form (pop-up)
>
>
> "JornyO" <JornyO[ at ]discussions.microsoft.com> wrote in message
> news:CD7CD70C-80DC-4B3E-A564-91D3556F2E5F[ at ]microsoft.com...
> > In a Macro I am creating, I need to import a delimited text file. Rather
> > than using a simple text box for someone to enter the file name, can a
> > dialogue box open so that the user can browse to find the correct file?
> >
> > Right now in the TransferText action in the Macro, I use the following for
> > the filename:
> > =InputBox("Filename")
> >
> > Is there a simple way to replace this input box with a file browsing box?
>
>
>
|
|
Jorny,
No, there is not any way to directly do this with a macro. This will
require the use of VBA code. See this article...
http://www.mvps.org/access/api/api0001.htm
--
Steve Schapel, Microsoft Access MVP
JornyO wrote:
[Quoted Text] > In a Macro I am creating, I need to import a delimited text file. Rather
> than using a simple text box for someone to enter the file name, can a
> dialogue box open so that the user can browse to find the correct file?
>
> Right now in the TransferText action in the Macro, I use the following for
> the filename:
> =InputBox("Filename")
>
> Is there a simple way to replace this input box with a file browsing box?
|
|
Hi Steve,
Thanks for the answer. After looking at that VBA code (which was way over
my head...I am not at all a programmer), I noticed that it makes mention of a
function called GetOpenFile. I used the following in my Access Macro (in
Access 2003):
=GetOpenFile("Name of File")
This worked perfectly. Just thought I'd pass that on.
"Steve Schapel" wrote:
[Quoted Text] > Jorny, > > No, there is not any way to directly do this with a macro. This will > require the use of VBA code. See this article... > http://www.mvps.org/access/api/api0001.htm> > -- > Steve Schapel, Microsoft Access MVP > > JornyO wrote: > > In a Macro I am creating, I need to import a delimited text file. Rather > > than using a simple text box for someone to enter the file name, can a > > dialogue box open so that the user can browse to find the correct file? > > > > Right now in the TransferText action in the Macro, I use the following for > > the filename: > > =InputBox("Filename") > > > > Is there a simple way to replace this input box with a file browsing box?
|
|
Actually...maybe not so perfectly. The dialogue box seems to only want to
allow me open .mdb files. I'll start a new thread and see if anyone has any
suggestions. Thanks for your help so far.
"JornyO" wrote:
[Quoted Text] > Hi Steve, > > Thanks for the answer. After looking at that VBA code (which was way over > my head...I am not at all a programmer), I noticed that it makes mention of a > function called GetOpenFile. I used the following in my Access Macro (in > Access 2003): > > =GetOpenFile("Name of File") > > This worked perfectly. Just thought I'd pass that on. > > > "Steve Schapel" wrote: > > > Jorny, > > > > No, there is not any way to directly do this with a macro. This will > > require the use of VBA code. See this article... > > http://www.mvps.org/access/api/api0001.htm> > > > -- > > Steve Schapel, Microsoft Access MVP > > > > JornyO wrote: > > > In a Macro I am creating, I need to import a delimited text file. Rather > > > than using a simple text box for someone to enter the file name, can a > > > dialogue box open so that the user can browse to find the correct file? > > > > > > Right now in the TransferText action in the Macro, I use the following for > > > the filename: > > > =InputBox("Filename") > > > > > > Is there a simple way to replace this input box with a file browsing box? > |
|
Hi JornyO, try this.
Create a module and call it "TOOLS"
copy the code below into it.
then run the function TESTIT()
It is easy to read and follow with the debugger.
Scott Burke
'***************** Code Start **************
'This code was originally written by Ken Getz.
'It is not to be altered or distributed,
'except as part of an application.
'You are free to use it in any application,
'provided the copyright notice is left unchanged.
'
' Code courtesy of:
' Microsoft Access 95 How-To
' Ken Getz and Paul Litwin
' Waite Group Press, 1996
Type tagOPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type
Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long
Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000
Function TestIt()
Dim strFilter As String
Dim lngFlags As Long
strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda, *.mdb)", _
"*.MDA;*.MDB")
strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)", "*.DBF")
strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)", "*.TXT")
strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")
MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\", _
Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
DialogTitle:="Hello! Open Me!")
' Since you passed in a variable for lngFlags,
' the function places the output flags value in the variable.
Debug.Print Hex(lngFlags)
End Function
Function GetOpenFile(Optional varDirectory As Variant, _
Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
lngFlags = ahtOFN_FILEMUSTEXIST Or _
ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
If IsMissing(varDirectory) Then
varDirectory = ""
End If
If IsMissing(varTitleForDialog) Then
varTitleForDialog = ""
End If
' Define the filter string and allocate space in the "c"
' string Duplicate this line with changes as necessary for
' more file templates.
strFilter = ahtAddFilterItem(strFilter, _
"Access (*.mdb)", "*.MDB;*.MDA")
' Now actually call to get the file name.
varFileName = ahtCommonFileOpenSave( _
OpenFile:=True, _
InitialDir:=varDirectory, _
Filter:=strFilter, _
Flags:=lngFlags, _
DialogTitle:=varTitleForDialog)
If Not IsNull(varFileName) Then
varFileName = TrimNull(varFileName)
End If
GetOpenFile = varFileName
End Function
Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal FileName As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hwnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.
If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(FileName) Then FileName = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(FileName & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With OFN
.lStructSize = Len(OFN)
.hwndOwner = hwnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With
' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(OFN)
Else
fResult = aht_apiGetSaveFileName(OFN)
End If
' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = OFN.Flags
ahtCommonFileOpenSave = TrimNull(OFN.strFile)
Else
ahtCommonFileOpenSave = vbNullString
End If
End Function
Function ahtAddFilterItem(strFilter As String, _
strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.
If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & _
strDescription & vbNullChar & _
varItem & vbNullChar
End Function
Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
intPos = InStr(strItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(strItem, intPos - 1)
Else
TrimNull = strItem
End If
End Function
|
|
Pretty sure this is the same code that Jorny has already been using, Scott.
--
Steve Schapel, Microsoft Access MVP
Scott Burke wrote:
[Quoted Text] > Hi JornyO, try this.
> Create a module and call it "TOOLS"
> copy the code below into it.
> then run the function TESTIT()
|
|
|